home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Magnum One
/
Magnum One (Mid-American Digital) (Disc Manufacturing).iso
/
d1
/
amac34.arc
/
MACR27.QM
< prev
next >
Wrap
Text File
|
1991-02-16
|
35KB
|
752 lines
* (MacroMaker) MACR27.QM, v2.7b
* ┌────────────────────────[ (Index) of Macros ]───────────────────────────────┐
* │(Alt_2) - Refresh with "standard" macfile
* │(Alt_3) - Merges current macros with designated txtfile, reads macfile
* │(Alt_4) - Appends txtfile to "standard" txtfile & macfile, reads macfile
* │(Alt_5) - Gets error files in window
* │(Alt_6) - Makes dummy txtfile from current macros
* │(Alt_7) - Makes & reads dummy macfile from txtfile
* │(Alt_t) - Makes & reads dummy macfile from txtfile, SMALL
* │(Alt_8) - Reads macfile of txtfile
* │(Alt_9) - Makes macfile only of txtfile
* │(Alt_0) - Makes & reads macfile of txtfile
* │(Alt_q) - Makes & reads macfile of txtfile, SMALL
* │
* │(Alt_f1)- Makes single column macro
* │(Alt_f2)- Puts command key beside a single command in a macro
* │(Alt_f3)- Puts command key beside ALL commands in a macro
* │(Alt_f4)- Gets a single command and it's key on screen
* │
* │(Alt_h) Select Index item with cursor line, then <enter>.
* │
* │(Index) Use - How to locate macro or item from Index using @h
* │(Description) - MacroMaker Macros
* │(Requirements) - and use
* │(Startup) - See MACR.DOC for startup instructions
* │(Macros) - MacroMaker Macros
* │(Other) Macros - not included
* │(Version) history
* └────────[ be sure to leave at least one blank line at end of Index ]────────┘
* (Index) Use;
*
* To locate a macro or item in this file, press @h, place the cursor
* line on the desired item in the Index above, and press <enter>.
* See BOOK15.QM for more details.
* (Description):
* (MacroMaker) MACR27.ZIP Contains QEdit macros to easily convert
* macros to & from text/binary (txtfile/macfile) using QMAC macro
* translator:
* (Requirements) and Use (see MACR.DOC for (startup) instructions):
*
* 1. Txtfile name extension MUST be [file].QM, Macfile [file].MAC.
* 2. Change ram disk c:\ (also in batch files) for your setup.
* Ram disk is optional but faster than a hard drive. Use any
* active drive letter to replace c:\.
* 3. Batch files must be in path or current directory. INSERT must
* be ON. Run macros and press Enter to continue when paused.
* 4. Modify "g:\qe\MACROS.xxx" in macros to your "standard" macro.
* Be careful to use or not use extension as shown, with spaces.
* 5. Be sure to change "g:\qe\qconfig.dat" in the macros @f2 -
* @f4 below to the location of your qconfig.dat in your
* setup, and convert with QMAC.
* In order for macros @f2 - @f4 to find a command in QCONFIG.DAT, there
* must be at least four blank spaces betweeen the end of the command
* key and the beginning of the command. If your QCONFIG.DAT has fewer
* spaces, the macros must be modified in the first 'FIND' line.
* Insert must be ON.
* Replacing C:\ with a ram drive will make the macros run considerably
* faster.
* These macros require "QEdit and QMAC v2.1, February, 1990" or later.
*
* To BEGIN, just type "START MACR" <Enter>. All pertinent files will be
* loaded in the "Ring" for viewing, and MACR27.MAC is read.
* Alternatively, type "START MACR 0" <Enter> and the disk copies of all
* files in the "Ring" will be loaded ready for editing, saving time.
* --------------------------(Macros)---------------------------------
*
*┌───────────────────────────────────────────────────────────┐
*│(Alt_2) Refreshes macro buffer with "standard" macfile │
*└───────────────────────────────────────────────────────────┘
* Remember to modify "g:\qe\macros.mac" with your "standard" macfile.
*
@2 MacroBegin MacroRead "g:\qe\macros.mac" Return
*
* 38 bytes Thu 07-26-1990 02:16:58
* 38 bytes Fri 09-14-1990 14:05:43
*┌────────────────────────────────────────────────────────────────┐
*│(Alt_3) Merges designated txtfile [file].qm with current macros │
*└────────────────────────────────────────────────────────────────┘
*
@3 macrobegin
editfile "c:$" return killfile quit * gets macro to
editfile return return * be merged with
"Merge macro ? "return cursorup endline cursorright pause *
cursorleft markword cut killfile quit * *
macrowrite "dum4.mac" return return * write cur macros
DOS "qmacM " paste return return * makes apnd macro
horizontalwindow *
editfile "c:!" return quit editfile return * get error file
insertdate inserttime * put date in c:!
find "(" return return
jfalse NOERROR: * get error line #
wordright unmarkblock markblockbegin wordright *
cursorleft markblockend copy savefile prevwindow *
gotoline paste return makectrofscreen pause zoomwindow * go to error #1
jump CONTINUE: *
NOERROR:
prevwindow zoomwindow * no error, back
CONTINUE:
editfile "dum4.qm" return * load apnd. txtfil
splitline newfile "N" return endfile return *
"*...Tom Hogshead " insertdate inserttime * stamp bottom
"Appended " paste endline ".qm to current macros" * w/ date/time
unmarkblock savefile macroread "dum4.mac" return * read apnd. macfil
*
* 288 bytes Thu 07-26-1990 02:17:16
* 273 bytes Fri 09-14-1990 14:05:47
*┌───────────────────────────────────────────────────────────┐
*│(Alt_4) Appends txtfile [file].qm to a "standard" txtfile │
*│ named macros.qm and reads appended macfile. │
*└───────────────────────────────────────────────────────────┘
* Remember to modify "g:\qe\macros" (no extension) in this
* macro to your "standard" macfile.
*
@4 macrobegin
unmarkblock * unmarkblock
savefile DOS "qmacTA2 " currentfilename * make file.mac
backspace backspace backspace " " *
"g:\qe\macros" return **(no EXTension)** **
begline insertline dropanchor currentfilename * get name to scrch
storescrbuff "1" return cut *
editfile "c:!" return quit * quit c:!
editfile paste return horizontalwindow * load file.qm
editfile "c:!" return * get error file
insertdate inserttime * put date in c:!
find "(" return return
jfalse NOERROR: * get error line #
wordright unmarkblock markblockbegin wordright *
cursorleft markblockend copy savefile prevwindow *
gotoline paste return makectrofscreen pause zoomwindow * go to error line
jump CONTINUE: *
NOERROR: *
prevwindow zoomwindow * no error, go to
CONTINUE:
editfile "c:$" return quit *
editfile return killfile * load dum3.qm
editfile "dum3.qm" return quit
editfile return * load dum3.qm
begfile cursordown endline * stamp
cursorright
"from:" cursorright
getscrbuff "1" return
unmarkblock endfile return * line on bot
"*" cursorright "Tom Hogshead"
cursorright cursorright
insertdate inserttime * - name/date bot
"Appnd:" cursorright
getscrbuff "1" return unmarkblock * - file on bot
savefile macroread currentfilename * read dum3.mac
backspace backspace "MAC" return *
*
* 251 bytes Thu 07-26-1990 09:00:10
* 228 bytes Fri 09-14-1990 14:05:51
*┌──────────────────────────────────────────────────────────────┐
*│(Alt_5) Gets error file (c:!) in window. Press ENTER to remove│
*└──────────────────────────────────────────────────────────────┘
*
@5 macrobegin
horizontalwindow * make window
editfile "c:!" return * load c:!
makectrofscreen pause zoomwindow * zoom on pause
quit * quit c:!
*
* 30 bytes Thu 07-26-1990 09:03:05
* 17 bytes Fri 09-14-1990 14:05:55
* ┌────────────────────────────────────────────┐
* │ (Alt_6) Makes textfile from current macros │
* └────────────────────────────────────────────┘
*
@6 macrobegin
macrowrite "c:$.mac" return return * write to c:$.mac
DOS "qmact c:$" return return * make c:$.qm
editfile "c:$.qm" return quit * quit old c:$.qm
editfile return * load new c:$.qm
killfile * kill c:$.qm
endfile * to see newest macro
*
* 61 bytes Sat 09-15-1990 14:26:40
*┌───────────────────────────────────────────────────────────┐
*│ (Alt_7) Copies txtfile [file].QM to dummy txtfile. │
*│ Makes and reads macfile. │
*└───────────────────────────────────────────────────────────┘
*
@7 macrobegin
unmarkblock writeblock "c:$.qm" return * copy file.qm
begline insertline dropanchor currentfilename * get name
storescrbuff "1" return cut * to scratch
editfile "c:$.qm" return quit editfile return * load c:$.qm
DOS "qmacbj c:$" return * make c:$.mac
begline insertline dropanchor currentfilename cut * get name to scrap
editfile "c:!" return quit * quit c:!
editfile paste return horizontalwindow * load file.qm
editfile "c:!" return * load error file
insertdate inserttime * put date in c:!
find "(" return return *
jfalse NOERROR: * get error line #
wordright unmarkblock markblockbegin wordright *
cursorleft markblockend copy savefile prevwindow *
gotoline paste return makectrofscreen pause zoomwindow * go to error line
jump CONTINUE: *
NOERROR: *
prevwindow zoomwindow * no error, back
CONTINUE: *
DOS "qmact c:$" return return * make c:$.qm
editfile "c:$.qm" return quit editfile return * load c:$.qm
endfile addline *
"*" insertdate inserttime * - name/date bot
getscrbuff "1" return unmarkblock * - file on bot
killfile * kill c:$.qm
macroread currentfilename * read c:$.mac
backspace backspace "MAC" return *
*
* 194 bytes Thu 08-21-1980 19:54:29
* 184 bytes Fri 09-14-1990 14:06:03
*┌───────────────────────────────────────────────────────────┐
*│ (Alt_t) Copies txtfile [file].QM to dummy txtfile. │
*│ Makes and reads macfile, small version │
*└───────────────────────────────────────────────────────────┘
* This is an alternate version of @7. Errors during macro conversion are
* not saved in an error window. It is much smaller than @7.
@t MacroBegin *
unmarkblock *
WriteBlock "c:$.qm" Return * copy file/block to temp file
DOS "qmacb c:$" Return Return * make temp macfile
DOS "qmact c:$" Return Return * make temp txtfile
EditFile "c:$.qm" Return Quit * quite temp file from ring
EditFile Return * load temp txtfile
killfile * kill temp file
MacroRead "c:$.Mac" Return * read temp macfile
*
* 95 bytes Fri 09-14-1990 14:06:07
*┌───────────────────────────────────────────────────────────┐
*│(Alt_8) READS macfile from txtfile [file].QM │
*└───────────────────────────────────────────────────────────┘
*
@8 macrobegin
macroread currentfilename backspace backspace "mac" return
*
* 15 bytes Thu 07-26-1990 02:18:38
* 15 bytes Fri 09-14-1990 14:06:11
*┌───────────────────────────────────────────────────────────┐
*│(Alt_9) Makes macfile from txtfile [file].QM, NO read │
*└───────────────────────────────────────────────────────────┘
*
@9 macrobegin savefile DOS "qmacb " currentfilename * make file.mac
backspace backspace backspace return * remove ".qm"
*
* 23 bytes Thu 07-26-1990 02:18:56
* 23 bytes Fri 09-14-1990 14:06:14
*┌───────────────────────────────────────────────────────────┐
*│(Alt_0) Makes macfile from txtfile [file].QM │
*│ Loads macfile [file].MAC, With error window. │
*└───────────────────────────────────────────────────────────┘
*
@0 macrobegin
savefile DOS "qmacbj " currentfilename * make file.mac
backspace backspace backspace return *
unmarkblock insertline begline * insert temp line
dropanchor currentfilename cut * cut name to scrap
editfile "c:!" return quit * quit c:!
editfile paste return horizontalwindow * load file.qm
editfile "c:!" return * get error file
insertdate inserttime * put date in c:!
find "(" return return * get error line #
jfalse NOERROR: *
wordright unmarkblock markblockbegin wordright *
cursorleft markblockend copy savefile prevwindow *
gotoline paste return makectrofscreen pause zoomwindow * go to error line
jump CONTINUE: *
NOERROR: *
prevwindow zoomwindow * no error, back
CONTINUE: *
macroread currentfilename backspace backspace "mac" return* read new macro
*
* 98 bytes Thu 07-26-1990 09:08:31
* 93 bytes Fri 09-14-1990 14:18:31
*┌───────────────────────────────────────────────────────────┐
*│(Alt_q) Makes macfile from txtfile [file].QM │
*│ Loads macfile [file].MAC, NO error window, SMALL. │
*└───────────────────────────────────────────────────────────┘
*
@q macrobegin
savefile DOS "qmacb " currentfilename * make file.mac
backspace backspace backspace return return *
macroread currentfilename backspace backspace "mac" return* read new macro
*
* 35 bytes Fri 09-14-1990 14:06:22
*┌───────────────────────────────────────────────────────────────────┐
*│(Alt_h) Finds first word on cursor line marked in document below │
*└───────────────────────────────────────────────────────────────────┘
*
* Alt_h macro has 2 steps:
*
* 1. Press Alt and h at the same time. An ! shows at the
* end of the top line. Cursor down to desired line in Index.
*
* 2. Press Enter. The macro first erases the !, and
* then finds the first word on the cursor line in the document
* below marked with (...).
*
*
@h macrobegin
unmarkblock * unmark any marked blocks
begfile endline * go to file begin endline
"!" * put ! at endline
begline
find "!" return return begline * highlight !
pause * pause for Index selection
wordright markword * mark first word on line
copy * copy word to scrap buffer
begfile * begfile
find "!" return return delch * find & delete !
endpara * go to end of Index
makectrofscreen * cursor line center of window
find "(" paste ")"
return "I" return * find first marked word in doc
jfalse NOMARK:
begline * if mark found go to begline
jump END:
NOMARK:
begfile * if no mark found go to begfile
END:
*
* 47 bytes Thu 07-26-1990 13:02:27
* 47 bytes Fri 09-14-1990 14:06:26
* ┌────────────────────────────────────┐
* │(Alt_f1) Makes single column macro │
* └────────────────────────────────────┘
* If a macro is not a marked block, the full txtfile is made into a
* single column macro.
*
* To make a single column macro with Alt_f1, place the cursor line
* anywhere in a macro txtfile (after loading the macfile) and press Alt
* and f1 at the same time.
@f1 macrobegin
writeblock "c:$.qm" return * copy block or file to c:$.qm
unmarkblock insertline begline * insert temp line
dropanchor currentfilename cut * cut currentfilename to scrap
DOS "qmacb c:$" return return * make macfile
DOS "qmact-n c:$" return return * make txtfile
editfile "c:$.qm" return quit *
editfile return * load c:$.qm
endfile addline * insert blank line at end
"* " insertdate inserttime * for date/time
paste unmarkblock * get file name on line
killfile * kill c:$.qm
*
* 98 bytes Fri 09-14-1990 14:06:30
*┌──────────────────────────────────────────┐
*│ (Alt_f2) Puts key beside single command │
*└──────────────────────────────────────────┘
* To get the key for a single command in a macro, place the cursor line
* on the command in a single column macro txtfile and press Alt_f2. The
* key corresponding to the command will be listed next to the commmand.
@f2 macrobegin
unmarkblock insertline begline * insert temp line
dropanchor currentfilename *
storescrbuff "1" return * get to scrbuff
cut * delete temp line
begline wordright markword * get to command, mark it
copy * get to scrap
unmarkblock * unmark
editfile *
"g:\qe\qconfig.dat" ** CHANGE for your setup **
return * load qconfig.dat
begfile * go to begin qconfig.dat
FIND " " * insert 4 spaces before find
paste * paste command for find
return "IW" return * find command in qconfig.dat
jfalse NOFIND: * mark if found, quit if not
wordright markcolumn * move cursor to command
begline * go to begline
"* " * insert asterisk space
begline markcolumn * go to begline, include key
storescrbuff "2" return * get key to scrbuff
cursordown * move down line
unmarkblock * unmark command
quit * quit qconfig.dat
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * load currentfilename
markcolumn * start to mark block
gotocolumn "33" return * postition to get key
getscrbuff "2" return * get key
begline * go to begline
makectrofscreen * for better viewing
cursordown * move down to next command
jump END: * stop after getting key
NOFIND: * come here if no key for command
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * return to file
gotocolumn "33" return * position to get key
"* " * insert asterisk space
cursordown * move down to next command
begline *
END: *
*
* 136 bytes Fri 09-14-1990 14:06:35
*┌────────────────────────────────────────────────────────────────┐
*│ (Alt_f3) Puts key beside ALL commands in single column macfile │
*└────────────────────────────────────────────────────────────────┘
* To get the keys for ALL commands in a macro, place the cursor
* line at the top of a macro txtfile and press Alt_f3. An example of
* this output is shown at the end of this macro. The keys corresponding
* to each command will be listed also in a single column next to the
* command.
@f3 macrobegin
unmarkblock insertline begline * insert temp line
dropanchor currentfilename *
storescrbuff "1" return *
cut * delete temp line
START: *
endline begline * line blank? if so end
jfalse END: *
begline wordright markword *
copy unmarkblock * get command to scrap, unmark
editfile *
"g:\qe\qconfig.dat" ** CHANGE for your setup **
return * load qconfig.dat
begfile * go to begin qconfig.dat
FIND " " * insert 4 spaces before find
paste * paste command for find
return "IW" return * find command in qconfig.dat
jfalse NOFIND: * mark if found, quit if not
wordright markcolumn begline * move cursor to command
"* " begline markcolumn * insert asterisk space
storescrbuff "2" return * get key to scratch
cursordown unmarkblock * move down line, unmark command
quit * quit qconfig.dat
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * load currentfilename
markcolumn * start to mark block
gotocolumn "33" return * postition to get key
getscrbuff "2" return * get key
begline makectrofscreen * for better viewing
cursordown * move down to next command
jump START: * start on next command
NOFIND: * come here if no key for command
getscrbuff "1" return * get currentfilename
cut * cut currentfilename
editfile paste return * return to file
gotocolumn "33" return * position to get key
"* " * insert asterisk space
cursordown * move down to next command
begline *
jump START: * do next line till done
END: *
*
* 144 bytes Fri 09-14-1990 14:06:40
*-----------------
* Here is what the macro Alt_f1 looks like by first marking it as a
* block, then running @f1 by placing the cursor line on the line
* below @f1 in c:$.qm and running @f3. (NOTE: an asterisk and
* space have been added to column 1)
* *
* * Converted by QMAC from: c:\$.mac
* *
* @f1 Macro_Begin <- (modified for SIZE macro)
* WriteBlock * @w
* "c:$." *
* "qm" *
* Return * enter
* UnmarkBlock * @u
* InsertLine * ^n_i
* BegLine * home
* DropAnchor * @a
* CurrentFilename * ^n_n
* Cut * ^c_u
* DOS "" * ^n_o
* "qmacb " *
* "c:$" *
* Return * enter
* Return * enter
* DOS "" * ^n_o
* "qmact-" *
* "n c:$" *
* Return * enter
* Return * enter
* EditFile * f3
* "c:$." *
* "qm" *
* Return * enter
* Quit * @x
* EditFile * f3
* Return * enter
* EndFile * ^pgdn
* AddLine * ^n_j
* "* "
* InsertDate * ^d
* InsertTime * ^e
* Paste * ^c_p
* UnmarkBlock * @u
* KillFile * ^k_z
*
* * Thu 09-13-1990 13:03:03 e:\up\getc13.qm
* ┌───────────────────────────────────────────────────────────────┐
* │ (Alt_f4) Retrieves a command and it's key from QCONFIG.DAT │
* └───────────────────────────────────────────────────────────────┘
* This macro retrieves a command or all commands matching a selected
* find criteria from your QCONFIG.DAT file, displays the selected
* command(s) and it's key on the screen, and then removes the
* command(s) and it's key from the screen. For those of us who can
* never remember all the commands and can never find our reference
* sheet, this might help.
* To run, press Alt_f4, then enter the first letter (or more) of the
* command you want to know the key for, press 'Enter' to see the the
* command(s) and it's key, then press 'Enter' again to remove the
* command(s) and it's key from the screen.
*
* For example, to find the key for appendscrbuff, press:
* <Alt_f4>
* app
* <Enter>
*
* You should see the following highlighted on your screeen:
*
* |
* ^b_a appendscrbuff |
*
*
* Entering "b" instead shows all commands beginning with "b":
*
* |
* ^h backspace |
* ^home begscreen |
* ^pgup begfile |
* home begline |
* backspace backspace |
*
*
* Press 'Enter' to remove the command(s) and it's key from the screen,
* or press 'Esc' three times if you want to keep the command(s) on the
* screen for reference.
@f4 macrobegin
unmarkblock insertline begline * insert temp line
dropanchor currentfilename *
cut * delete temp line
editfile *
"g:\qe\qconfig.dat" ** CHANGE for your setup **
dropanchor * start to clear scrap
storescrbuff "1" return * get to scrap
unmarkblock begfile * go to begin qconfig.dat
FIND " " * insert 4 spaces before find
pause * pause for command to find
return "i" return * find first command
jump NEXT: *
START: * come here more than 1 find
find return "i" return * find next command
NEXT: *
jfalse FINISH: * mark if found, quit if not
markline begline * mark command line
"* " * asterisk space
appendscrbuff "1" return * get to scrbuff
cursordown unmarkblock * move down line, unmark command
jump START: * see if any more matches
FINISH: * come here after last find
quit * quit qconfig.dat
editfile paste return * return to file
markcolumn * start to mark block
getscrbuff "1" return * get command and key
delline begline * delete blank line, begline
maketopofscreen * for better viewing
pause * pause, then 'Enter' to..
deleteblock * clean up, remove block
*
* 106 bytes Fri 09-14-1990 14:06:49
* (Other) Macros available: See ALLMACRO.INF.
*
* (Version) History:
*
* 1.0 - initial version
* 1.1 - Changed Alt-6 to keep [file].qm in ring after running.
* 1.2 - Date & time stamp put in dum.qm (Alt-6, Alt-7).
* 1.3 - Added batch files to macro13.ZIP.
* 1.4 - Changed Alt-6 & 7 to stamp [file].QM translated from.
* - Changed Alt-0 to not pause if no errors.
* - Added Alt-5 to see error files in window.
* - Changed /W60 to /W70 and removed "pause" in qmact.bat.
* 1.5 - Changed Alt-7 to not pause if no errors.
* 1.6 - Shortened Alt-6, 7 & 10. Faster & no pause now if no errors.
* 1.7 - Corrected Alt-6 to write macros first. Sorry.
* 1.8 - Added Alt-4 to append text file [file].qm macros
* to a "standard" macro and read appended macro.
* 1.9 - Added Alt-3 to merge designated macro [file].mac
* with current macros. QEdit normally overwrites
* current macros when reading a new macro.
* 2.0 - Added Alt-2 to refresh macro buffer with "standard" macro.
* - New qmacTA2.bat for Alt-4, gets "standard" name as %2.
* - Added Alt T & Alt N to select txtfile to read from
* sorted list of all avaialable txtfiles in directory.
* - New SORT-T.BAT and SORT-F.BAT for Alt T & N to sort macro list.
* - Changed Alt-4 to identify "standard" rather than batch file.
* (Modify g:\qe\macros for the name of your "standard" macro.)
* - Shortened Alt-3,7 & 0, total 91 bytes. (Important when merging
* since QEdit macro buffer is limited to 2046 bytes macros.)
* - Moved macroread to end of Alt-3. No problem, just in case.
* (Reading macros while executing can sometimes cause problems.)
* - Changed Alt-5 to refresh c:!.
* 2.1 - (Internal)
* 2.2 - Added Alt-1 to select txtfile to load from list of all txtfiles
* in directory sorted by Name. Added sort-N2.bat for this macro.
* - Changed Alt T & Alt N to select macfile, not txtfile as v2.0,
* from sorted list of all available macfiles in directory.
* - Changed sort-T.bat, sort-N.bat and sort-N1.bat for macr s.
* - Renamed MACCMTxx to MACROxx. Dropped MACCMTxx. Macros comments
* and instructions are now are in MACROxx.qm.
* - Shortened highlight bar in Alt N,t. Saves ~30 bytes/macro.
* - Changed dum.dir to $ in Alt-4 & qmacTA2.bat to shorten
* - Added killfile to Alt-3 & 4. Changed endfile display in Alt-4.
* - Replaced "j:\j" with "c:!" in macros and batch files to shorten.
* - Changed qmacTA2.bat for better display.
* - Changed select window from "c:!" to "c:$" in batch files
* - Sort batch files (sort-xx.bat) also changed.
* 2.3 - Changed @5 to keep error file c:! in ring.
* - By removing " "'s, changing file name tracking in buffers,
* and shortening header and footer labels:
* - shortened @4 28 bytes
* - shortened @5 5 "
* - shortened @6 67 "
* - shortened @7 24 "
* - shortened @9 3 "
* - Added macro size 'bytes line' at end of each macro
* 2.4 - Removed dum.qm and dum.mac from zip package
* - Shortened Alt_6 from 147 to 54 bytes
* - Shortened Alt_7 from 258 to 194 bytes
* 2.4a - Modified @6 and description
* 2.4b - Modified documentation.
* 2.4c - Changed file name from MACROxx to MACRxx.
* 2.5 - Changed j:j to c:! in macros and batch files.
* - Changed down arrow #25 to ! in ^0.
* - Changed .LST and .QL files.
* - Removed @1, @t and @n. Newer macros to do the same thing
* are in FILExx.ZIP.
* 2.6 - Added @t, smaller faster version of @7.
* - Added @q, smaller faster version of @0.
* - Added @f1, @f2, @f3 and @f4 from GETCxx.ZIP and COLxx.ZIP,
* which are no longer included as seperate files, but are now
* a part of MACRxx.ZIP.
* - Modified and shortened all but @2, @6, @8, @9 and ^1.
* - Added killfile to @6 so writeblock return works correctly.
* 2.6a - Changed ^1 help macro key to @h key.
* 2.7 - Removed [d:]\[path] for location of QMAC from QMACxxx batch
* files. QMAC can be located anywhere in path.
* 2.7a - Modified documentation and added START.BAT.
* - Change MACRO file names to MACR.
* 2.7b - Corrected @h Index Use instructions.
* error_sample, remove asterisk to test for errors
*
* Tom Hogshead Fri 01-11-1991